home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 1999 August / SGI Freeware 1999 August.iso / dist / fw_emacs.idb / usr / freeware / share / emacs / 19.34 / lisp / server.el.z / server.el
Encoding:
Text File  |  1998-10-28  |  16.4 KB  |  421 lines
  1. ;;; server.el --- Lisp code for GNU Emacs running as server process.
  2.  
  3. ;; Copyright (C) 1986, 1987, 1992, 1994, 1995 Free Software Foundation, Inc.
  4.  
  5. ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
  6. ;; Keywords: processes
  7.  
  8. ;; Changes by peck@sun.com and by rms.
  9.  
  10. ;; This file is part of GNU Emacs.
  11.  
  12. ;; GNU Emacs is free software; you can redistribute it and/or modify
  13. ;; it under the terms of the GNU General Public License as published by
  14. ;; the Free Software Foundation; either version 2, or (at your option)
  15. ;; any later version.
  16.  
  17. ;; GNU Emacs is distributed in the hope that it will be useful,
  18. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20. ;; GNU General Public License for more details.
  21.  
  22. ;; You should have received a copy of the GNU General Public License
  23. ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24. ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25. ;; Boston, MA 02111-1307, USA.
  26.  
  27. ;;; Commentary:
  28.  
  29. ;; This Lisp code is run in Emacs when it is to operate as
  30. ;; a server for other processes.
  31.  
  32. ;; Load this library and do M-x server-edit to enable Emacs as a server.
  33. ;; Emacs runs the program ../arch-lib/emacsserver as a subprocess
  34. ;; for communication with clients.  If there are no client buffers to edit, 
  35. ;; server-edit acts like (switch-to-buffer (other-buffer))
  36.  
  37. ;; When some other program runs "the editor" to edit a file,
  38. ;; "the editor" can be the Emacs client program ../lib-src/emacsclient.
  39. ;; This program transmits the file names to Emacs through
  40. ;; the server subprocess, and Emacs visits them and lets you edit them.
  41.  
  42. ;; Note that any number of clients may dispatch files to emacs to be edited.
  43.  
  44. ;; When you finish editing a Server buffer, again call server-edit
  45. ;; to mark that buffer as done for the client and switch to the next 
  46. ;; Server buffer.  When all the buffers for a client have been edited 
  47. ;; and exited with server-edit, the client "editor" will return
  48. ;; to the program that invoked it.  
  49.  
  50. ;; Your editing commands and Emacs's display output go to and from
  51. ;; the terminal in the usual way.  Thus, server operation is possible
  52. ;; only when Emacs can talk to the terminal at the time you invoke
  53. ;; the client.  This is possible in four cases:
  54.  
  55. ;; 1. On a window system, where Emacs runs in one window and the
  56. ;; program that wants to use "the editor" runs in another.
  57.  
  58. ;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  59. ;; program that wants to use "the editor" runs on another.
  60.  
  61. ;; 3. When the program that wants to use "the editor" is running
  62. ;; as a subprocess of Emacs.
  63.  
  64. ;; 4. On a system with job control, when Emacs is suspended, the program
  65. ;; that wants to use "the editor" will stop and display
  66. ;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  67. ;; brought into the foreground for editing.  When done editing, Emacs is
  68. ;; suspended again, and the client program is brought into the foreground.
  69.  
  70. ;; The buffer local variable "server-buffer-clients" lists 
  71. ;; the clients who are waiting for this buffer to be edited.  
  72. ;; The global variable "server-clients" lists all the waiting clients,
  73. ;; and which files are yet to be edited for each.
  74.  
  75. ;;; Code:
  76.  
  77. (defvar server-program (expand-file-name "emacsserver" exec-directory)
  78.   "*The program to use as the edit server.")
  79.  
  80. (defvar server-visit-hook nil
  81.   "*List of hooks to call when visiting a file for the Emacs server.")
  82.  
  83. (defvar server-switch-hook nil
  84.   "*List of hooks to call when switching to a buffer for the Emacs server.")
  85.  
  86. (defvar server-done-hook nil
  87.   "*List of hooks to call when done editing a buffer for the Emacs server.")
  88.  
  89. (defvar server-process nil 
  90.   "the current server process")
  91.  
  92. (defvar server-previous-string "")
  93.  
  94. (defvar server-clients nil
  95.   "List of current server clients.
  96. Each element is (CLIENTID BUFFERS...) where CLIENTID is a string
  97. that can be given to the server process to identify a client.
  98. When a buffer is marked as \"done\", it is removed from this list.")
  99.  
  100. (defvar server-buffer-clients nil
  101.   "List of clientids for clients requesting editing of current buffer.")
  102. (make-variable-buffer-local 'server-buffer-clients)
  103. ;; Changing major modes should not erase this local.
  104. (put 'server-buffer-clients 'permanent-local t)
  105.  
  106. (defvar server-window nil
  107.   "*The window to use for selecting Emacs server buffers.
  108. If nil, use the selected window.
  109. If it is a frame, use the frame's selected window.")
  110.  
  111. (defvar server-temp-file-regexp "^/tmp/Re\\|/draft$"
  112.   "*Regexp which should match filenames of temporary files
  113. which are deleted and reused after each edit
  114. by the programs that invoke the emacs server.")
  115.  
  116. (or (assq 'server-buffer-clients minor-mode-alist)
  117.     (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist)))
  118.  
  119. ;; If a *server* buffer exists,
  120. ;; write STRING to it for logging purposes.
  121. (defun server-log (string)
  122.   (if (get-buffer "*server*")
  123.       (save-excursion
  124.     (set-buffer "*server*")
  125.     (goto-char (point-max))
  126.     (insert (current-time-string) " " string)
  127.     (or (bolp) (newline)))))
  128.  
  129. (defun server-sentinel (proc msg)
  130.   (cond ((eq (process-status proc) 'exit)
  131.      (server-log (message "Server subprocess exited")))
  132.     ((eq (process-status proc) 'signal)
  133.      (server-log (message "Server subprocess killed")))))
  134.  
  135. ;;;###autoload
  136. (defun server-start (&optional leave-dead)
  137.   "Allow this Emacs process to be a server for client processes.
  138. This starts a server communications subprocess through which
  139. client \"editors\" can send your editing commands to this Emacs job.
  140. To use the server, set up the program `emacsclient' in the
  141. Emacs distribution as your standard \"editor\".
  142.  
  143. Prefix arg means just kill any existing server communications subprocess."
  144.   (interactive "P")
  145.   ;; kill it dead!
  146.   (if server-process
  147.       (progn
  148.     (set-process-sentinel server-process nil)
  149.     (condition-case () (delete-process server-process) (error nil))))
  150.   (condition-case () (delete-file "~/.emacs_server") (error nil))
  151.   (let* ((sysname (system-name))
  152.      (dot-index (string-match "\\." sysname)))
  153.     (condition-case ()
  154.     (delete-file (format "/tmp/esrv%d-%s" (user-uid) sysname))
  155.       (error nil))
  156.     ;; In case the server file name was made with a domainless hostname,
  157.     ;; try deleting that name too.
  158.     (if dot-index
  159.     (condition-case ()
  160.         (delete-file (format "/tmp/esrv%d-%s" (user-uid)
  161.                  (substring sysname 0 dot-index)))
  162.       (error nil))))
  163.   ;; If we already had a server, clear out associated status.
  164.   (while server-clients
  165.     (let ((buffer (nth 1 (car server-clients))))
  166.       (server-buffer-done buffer)))
  167.   (if leave-dead
  168.       nil
  169.     (if server-process
  170.     (server-log (message "Restarting server")))
  171.     ;; Using a pty is wasteful, and the separate session causes
  172.     ;; annoyance sometimes (some systems kill idle sessions).
  173.     (let ((process-connection-type nil))
  174.       (setq server-process (start-process "server" nil server-program)))
  175.     (set-process-sentinel server-process 'server-sentinel)
  176.     (set-process-filter server-process 'server-process-filter)
  177.     (process-kill-without-query server-process)))
  178.  
  179. ;Process a request from the server to edit some files.
  180. ;Format of STRING is "Client: CLIENTID PATH PATH PATH... \n"
  181. (defun server-process-filter (proc string)
  182.   (server-log string)
  183.   (setq string (concat server-previous-string string))
  184.   ;; If the input is multiple lines,
  185.   ;; process each line individually.
  186.   (while (string-match "\n" string)
  187.     (let ((request (substring string 0 (match-beginning 0)))
  188.       client
  189.       (files nil)
  190.       (lineno 1))
  191.       ;; Remove this line from STRING.
  192.       (setq string (substring string (match-end 0)))      
  193.       (if (string-match "^Error: " request)
  194.       (message "Server error: %s" (substring request (match-end 0)))
  195.     (if (string-match "^Client: " request)
  196.         (progn
  197.           (setq request (substring request (match-end 0)))
  198.           (setq client (list (substring request 0 (string-match " " request))))
  199.           (setq request (substring request (match-end 0)))
  200.           (while (string-match "[^ ]+ " request)
  201.         (let ((arg
  202.                (substring request (match-beginning 0) (1- (match-end 0)))))
  203.           (setq request (substring request (match-end 0)))
  204.           (if (string-match "\\`\\+[0-9]+\\'" arg)
  205.               ;; ARG is a line number option.
  206.               (setq lineno (read (substring arg 1)))
  207.             ;; ARG is a file name.
  208.             ;; Collapse multiple slashes to single slashes.
  209.             (setq arg (command-line-normalize-file-name arg))
  210.             (setq files
  211.               (cons (list arg lineno)
  212.                 files))
  213.             (setq lineno 1))))
  214.           (server-visit-files files client)
  215.           ;; CLIENT is now a list (CLIENTNUM BUFFERS...)
  216.           (setq server-clients (cons client server-clients))
  217.           (server-switch-buffer (nth 1 client))
  218.           (run-hooks 'server-switch-hook)
  219.           (message (substitute-command-keys
  220.             "When done with a buffer, type \\[server-edit]")))))))
  221.   ;; Save for later any partial line that remains.
  222.   (setq server-previous-string string))
  223.  
  224. (defun server-visit-files (files client)
  225.   "Finds FILES and returns the list CLIENT with the buffers nconc'd.
  226. FILES is an alist whose elements are (FILENAME LINENUMBER)."
  227.   ;; Bind last-nonmenu-event to force use of keyboard, not mouse, for queries.
  228.   (let (client-record (last-nonmenu-event t) (obuf (current-buffer)))
  229.     ;; Restore the current buffer afterward, but not using save-excursion,
  230.     ;; because we don't want to save point in this buffer
  231.     ;; if it happens to be one of those specified by the server.
  232.     (unwind-protect
  233.     (while files
  234.       ;; If there is an existing buffer modified or the file is modified,
  235.       ;; revert it.
  236.       ;; If there is an existing buffer with deleted file, offer to write it.
  237.       (let* ((filen (car (car files)))
  238.          (obuf (get-file-buffer filen)))
  239.         (if (and obuf (set-buffer obuf))
  240.         (if (file-exists-p filen)
  241.             (if (or (not (verify-visited-file-modtime obuf))
  242.                 (buffer-modified-p obuf))
  243.             (revert-buffer t nil))
  244.           (if (y-or-n-p
  245.                (concat "File no longer exists: "
  246.                    filen
  247.                    ", write buffer to file? "))
  248.               (write-file filen)))
  249.           (set-buffer (find-file-noselect filen))
  250.           (run-hooks 'server-visit-hook)))
  251.       (goto-line (nth 1 (car files)))
  252.       (setq server-buffer-clients (cons (car client) server-buffer-clients))
  253.       (setq client-record (cons (current-buffer) client-record))
  254.       (setq files (cdr files)))
  255.       (set-buffer obuf))
  256.     (nconc client client-record)))
  257.  
  258. (defun server-buffer-done (buffer)
  259.   "Mark BUFFER as \"done\" for its client(s).
  260. This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED).
  261. NEXT-BUFFER is another server buffer, as a suggestion for what to select next,
  262. or nil.  KILLED is t if we killed BUFFER (because it was a temp file)."
  263.   (let ((running (eq (process-status server-process) 'run))
  264.     (next-buffer nil)
  265.     (killed nil)
  266.     (first t)
  267.     (old-clients server-clients))
  268.     (while old-clients
  269.       (let ((client (car old-clients)))
  270.     (or next-buffer 
  271.         (setq next-buffer (nth 1 (memq buffer client))))
  272.     (delq buffer client)
  273.     ;; Delete all dead buffers from CLIENT.
  274.     (let ((tail client))
  275.       (while tail
  276.         (and (bufferp (car tail))
  277.          (null (buffer-name (car tail)))
  278.          (delq (car tail) client))
  279.         (setq tail (cdr tail))))
  280.     ;; If client now has no pending buffers,
  281.     ;; tell it that it is done, and forget it entirely.
  282.     (if (cdr client) nil
  283.       (if running
  284.           (progn
  285.         ;; Don't send emacsserver two commands in close succession.
  286.         ;; It cannot handle that.
  287.         (or first (sit-for 1))
  288.         (setq first nil)
  289.         (send-string server-process 
  290.                  (format "Close: %s Done\n" (car client)))
  291.         (server-log (format "Close: %s Done\n" (car client)))))
  292.       (setq server-clients (delq client server-clients))))
  293.       (setq old-clients (cdr old-clients)))
  294.     (if (and (bufferp buffer) (buffer-name buffer))
  295.     (progn
  296.       (save-excursion
  297.         (set-buffer buffer)
  298.         (setq server-buffer-clients nil)
  299.         (run-hooks 'server-done-hook))
  300.       (if (server-temp-file-p buffer)
  301.           (progn (kill-buffer buffer)
  302.              (setq killed t))
  303.         (bury-buffer buffer))))
  304.     (list next-buffer killed)))
  305.  
  306. (defun server-temp-file-p (buffer)
  307.   "Return non-nil if BUFFER contains a file considered temporary.
  308. These are files whose names suggest they are repeatedly
  309. reused to pass information to another program.
  310.  
  311. The variable `server-temp-file-regexp' controls which filenames
  312. are considered temporary."
  313.   (and (buffer-file-name buffer)
  314.        (string-match server-temp-file-regexp (buffer-file-name buffer))))
  315.  
  316. (defun server-done ()
  317.   "Offer to save current buffer, mark it as \"done\" for clients.
  318. This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED).
  319. NEXT-BUFFER is another server buffer, as a suggestion for what to select next,
  320. or nil.  KILLED is t if we killed the BUFFER (because it was a temp file)."
  321.   (let ((buffer (current-buffer)))
  322.     (if server-buffer-clients
  323.     (progn
  324.        (if (server-temp-file-p buffer)
  325.           ;; For a temp file, save, and do make a non-numeric backup
  326.           ;; (unless make-backup-files is nil).
  327.           (let ((version-control nil)
  328.             (buffer-backed-up nil))
  329.         (save-buffer))
  330.         (if (and (buffer-modified-p)
  331.              (y-or-n-p (concat "Save file " buffer-file-name "? ")))
  332.         (save-buffer buffer)))
  333.       (server-buffer-done buffer)))))
  334.  
  335. ;; Ask before killing a server buffer.
  336. ;; It was suggested to release its client instead,
  337. ;; but I think that is dangerous--the client would proceed
  338. ;; using whatever is on disk in that file. -- rms.
  339. (defun server-kill-buffer-query-function ()
  340.   (or (not server-buffer-clients)
  341.       (yes-or-no-p (format "Buffer `%s' still has clients; kill it? "
  342.                (buffer-name (current-buffer))))))
  343.  
  344. (add-hook 'kill-buffer-query-functions
  345.        'server-kill-buffer-query-function)
  346.  
  347. (defun server-kill-emacs-query-function ()
  348.   (let (live-client
  349.     (tail server-clients))
  350.     ;; See if any clients have any buffers that are still alive.
  351.     (while tail
  352.       (if (memq t (mapcar 'stringp (mapcar 'buffer-name (cdr (car tail)))))
  353.       (setq live-client t))
  354.       (setq tail (cdr tail)))
  355.     (or (not live-client)
  356.     (yes-or-no-p "Server buffers still have clients; exit anyway? "))))
  357.  
  358. (add-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
  359.  
  360. (defun server-edit (&optional arg)
  361.   "Switch to next server editing buffer; say \"Done\" for current buffer.
  362. If a server buffer is current, it is marked \"done\" and optionally saved.
  363. When all of a client's buffers are marked as \"done\", the client is notified.
  364.  
  365. Temporary files such as MH <draft> files are always saved and backed up,
  366. no questions asked.  (The variable `make-backup-files', if nil, still
  367. inhibits a backup; you can set it locally in a particular buffer to
  368. prevent a backup for it.)  The variable `server-temp-file-regexp' controls
  369. which filenames are considered temporary.
  370.  
  371. If invoked with a prefix argument, or if there is no server process running, 
  372. starts server process and that is all.  Invoked by \\[server-edit]."
  373.   (interactive "P")
  374.   (if (or arg
  375.       (not server-process)
  376.       (memq (process-status server-process) '(signal exit)))
  377.       (server-start nil)
  378.     (apply 'server-switch-buffer (server-done))))
  379.  
  380. (defun server-switch-buffer (&optional next-buffer killed-one)
  381.   "Switch to another buffer, preferably one that has a client.
  382. Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it."
  383.   ;; KILLED-ONE is t in a recursive call
  384.   ;; if we have already killed one temp-file server buffer.
  385.   ;; This means we should avoid the final "switch to some other buffer"
  386.   ;; since we've already effectively done that.
  387.   (cond ((and (windowp server-window)
  388.           (window-live-p server-window))
  389.      (select-window server-window))
  390.     ((framep server-window)
  391.      (if (not (frame-live-p server-window))
  392.          (setq server-window (make-frame)))
  393.      (select-window (frame-selected-window server-window))))
  394.   (if (window-minibuffer-p (selected-window))
  395.       (select-window (next-window nil 'nomini 0)))
  396.   ;; Move to a non-dedicated window, if we have one.
  397.   (let ((last-window (previous-window nil 'nomini 0)))
  398.     (while (and (window-dedicated-p (selected-window))
  399.         (not (eq last-window (selected-window))))
  400.       (select-window (next-window nil 'nomini 0))))
  401.   (set-window-dedicated-p (selected-window) nil)
  402.   (if next-buffer
  403.       (if (and (bufferp next-buffer)
  404.            (buffer-name next-buffer))
  405.       (switch-to-buffer next-buffer)
  406.     ;; If NEXT-BUFFER is a dead buffer,
  407.     ;; remove the server records for it
  408.     ;; and try the next surviving server buffer.
  409.     (apply 'server-switch-buffer
  410.            (server-buffer-done next-buffer)))
  411.     (if server-clients
  412.     (server-switch-buffer (nth 1 (car server-clients)) killed-one)
  413.       (if (not killed-one)
  414.       (switch-to-buffer (other-buffer))))))
  415.  
  416. (global-set-key "\C-x#" 'server-edit)
  417.  
  418. (provide 'server)
  419.  
  420. ;;; server.el ends here
  421.